Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Remembering Copies to Print.

Remembering Copies to Print

by Allen Wyatt
(last updated August 6, 2011)

When you click on the Print tool, Word automatically prints a single copy of your document. It does this regardless of the number of copies you previously chose to print in the Print dialog box. This isn't some funny behavior unique to the Print tool. Indeed, each time you redisplay the Print dialog box you should notice that the Number of Copies setting is always reset to 1.

Word always seems to suffer from short-term memory loss in this area; the Number of Copies setting is simply not "persistent," and must be set each time you want to print. This can be bothersome, particularly if you want to print the same number of copies on a consistent basis.

There are two ways that a solution can be approached. First, you can create a macro that prints, using the currently selected printer, a specific number of copies. This is a great approach if you find yourself consistently printing a certain number of copies. The following macro, for example, will print four copies of the current document:

Sub PrintFour()
    ActiveDocument.PrintOut Copies:=4
End Sub

If you assign this macro to a new toolbar button or a shortcut key, then a simple click or key combination will print the desired number of copies.

The second solution is more involved, but may be more flexible in the long run. This solution involves the use of a custom document property to maintain, on a document-by-document basis, the number of copies last printed. This setting is used as the number of copies to print, thereby providing a persistent number of copies for each document. The following two macros should be used:

Public Sub FilePrint()
    Dim bExists As Boolean
    Dim MyPrint As Dialog

    ' ensure our doc variable exists
    bExists = False
    For Each varItem In ActiveDocument.CustomDocumentProperties
        If varItem.Name = "Copies" Then
            bExists = True
            Exit For
        End If
    Next varItem
    
    ' initialize document variable if doesn't exist
    If Not bExists Then
        ActiveDocument.CustomDocumentProperties.Add _
          Name:="Copies", LinkToContent:=False, _
          Type:=msoPropertyTypeNumber, Value:=1
    End If

    Set MyPrint = Dialogs(wdDialogFilePrint)
    With MyPrint
        .NumCopies = ActiveDocument.CustomDocumentProperties("Copies")
        .Show
    End With

    ActiveDocument.CustomDocumentProperties("Copies") = _
      MyPrint.NumCopies

    Set MyPrint = Nothing
End Sub
Public Sub FilePrintDefault()
    Dim bExists As Boolean

    ' ensure our doc variable exists
    bExists = False
    For Each varItem In ActiveDocument.CustomDocumentProperties
        If varItem.Name = "Copies" Then
            bExists = True
            Exit For
        End If
    Next varItem

    ' initialize document variable if doesn't exist
    If Not bExists Then
        ActiveDocument.CustomDocumentProperties.Add _
          Name:="Copies", LinkToContent:=False, _
          Type:=msoPropertyTypeNumber, Value:=1
    End If

    ActiveDocument.PrintOut Copies:= _
      CInt(ActiveDocument.CustomDocumentProperties("Copies"))
End Sub

These macros have special names, FilePrint and FilePrintDefault. These are the names assigned to the internal Word commands that display the Print dialog box (FilePrint) and print the active document (FilePrintDefault) through the use of the Print tool on the toolbar. When you use these macros, with the names shown, you essentially replace the internal Word commands.

In the case of the new FilePrint macro, the document properties are checked to see if there is one named Copies. If there is not, then a document property by that name is created and set to the value of 1. Then, the Print dialog box is displayed and the Number of Copies value is set based on the custom document property. You, as a user, can then change the Number of Copies setting, as desired. When the dialog box is closed (either by printing or not), the Copies document property is updated to whatever the Number of Copies setting was.

The FilePrintDefault macro, on the other hand, only checks to ensure that the Copies document property exists and sets the number of copies to print based on its value. If the property does not exist, then it is created and set to a value of 1.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1313) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Remembering Copies to Print.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Opening a Template

If you have a template stored on disk, you can open it and make changes to it just as you do other documents. This tip ...

Discover More

Turning Off Names

You can use some of the tools in Excel to convert cell references in formulas into names. Converting back (from names into ...

Discover More

Moving Text Using the Mouse

Many people use the keyboard to do their primary editing tasks. Word doesn't limit you to the keyboard, however. You can also ...

Discover More

Learning Made Easy! Quickly teach yourself how to format, publish, and share your content using Word 2013. With Step by Step, you set the pace, building and practicing the skills you need, just when you need them! Check out Microsoft Word 2013 Step by Step today!

More WordTips (menu)

Always Printing Drawing Objects

Add a bunch of drawing objects to your document, and you may wonder how to make sure they all appear on a printout. How you ...

Discover More

Peculiar Font Differences

Have you noticed page layout differences when you open a document on different systems? There are a number of reasons why ...

Discover More

Adding One More Line

It always seems to happen—you print a document and then discover that you should have included one more line of text at ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is two less than 2?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Word that uses the menu interface (Word 97, Word 2000, Word 2002, or Word 2003)? This site is for you! If you use a later version of Word, visit our WordTips site focusing on the ribbon interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.