Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Converting Paragraphs to Comments.

Converting Paragraphs to Comments

by Allen Wyatt
(last updated March 16, 2013)

When developing a document, it is not unusual to use a particular paragraph style for editorial notes. For instance, the notes may be stored in paragraphs using the Notes style. At some point, you may want to take all the paragraphs that use the Notes style and convert them to actual comments in the document. You can go through the document and make the conversion manually, but this can quickly get tedious. Instead, use a macro that does the conversion for you:

Sub ConvertNotesToComments()
    Dim CommentText As String
    Dim MyRange As Range
    Dim iPCount As Integer
    Dim J As Integer

    Application.ScreenUpdating = False
    iPCount = ActiveDocument.Paragraphs.Count

    For J = iPCount To 1 Step -1
        If ActiveDocument.Paragraphs(J).Style = _
          ActiveDocument.Styles("Notes") Then
            Set MyRange = ActiveDocument.Paragraphs(J).Range
            CommentText = MyRange.Text

            'Get rid of trailing end-of-paragraph mark
            CommentText = Left(CommentText, Len(CommentText) - 1)

            'Move selection to end of previous paragraph
            MyRange.Collapse (wdCollapseStart)
            MyRange.Move Unit:=wdCharacter, Count:=-1

            'The original paragraph is no longer necessary
            ActiveDocument.Paragraphs(J).Range.Delete

            'Create the comment at the range location
            ActiveDocument.Comments.Add Range:=MyRange, _
              Text:=CommentText
        End If
    Next J
    Application.ScreenUpdating = True
End Sub

The macro steps backwards through the document, looking at the style of each paragraph. If it finds one that uses the Notes style, then it moves the text of the paragraph into the CommentText variable, and then gets rid of the paragraph. The comment is then added to the end of the paragraph prior to where the deletion was made.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (5404) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Converting Paragraphs to Comments.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Using a Standard Format in a Suggested File Name

Many companies (and some individuals) use specific formats for naming their documents. If you want Word to recognize your ...

Discover More

Displaying All the Files in a Folder using Windows Explorer

Displaying all the files a folder contains is an easy task in Windows. One easy way to do it is by using the Windows ...

Discover More

Hyphenating Your Document

One of the final touches you can add to a document is to hyphenate it. This allows text to flow more smoothly from line to ...

Discover More

Create Custom Apps with VBA! Discover how to extend the capabilities of Office 2013 (Word, Excel, PowerPoint, Outlook, and Access) with VBA programming, using it for writing macros, automating Office applications, and creating custom applications. Check out Mastering VBA for Office 2013 today!

MORE WORDTIPS (MENU)

Pasting a Comment into Your Document

When developing a document, you may end up with all sorts of comments that you need to deal with. One common task is to copy ...

Discover More

Copying, Moving, and Deleting Comments

Comments are often added to documents to aid in their development. You can use regular editing techniques to copy, move, and ...

Discover More

Adding Comments to Your Document

If you would like to add non-printing notes to your document, the Comments feature is one way of doing that. Here's how to ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)

This Site

Got a version of Word that uses the menu interface (Word 97, Word 2000, Word 2002, or Word 2003)? This site is for you! If you use a later version of Word, visit our WordTips site focusing on the ribbon interface.

Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.

Links and Sharing
Share