Changing Text Case

I wish I could remove the ALL CAPS part of the Change Case macro when it's cycling through. I only capitalize or lowercase the letter.

Oh, this will save me a bundle of time. I edit documents in which people use all caps for emphasis and going through the Change Case dialog bow over and over and over gets tiresome. I don't know how I missed this one before. Thanks!

I keep a huge spreadsheet of my DVD/Blu-ray/4K disc collection. I do the bulk of film/TV title editing in Word, then copy/paste into Excel.

The native Word title case functionality is rather useless, so I adapted the Word Tip macro for Intelligent Title Case at https://word.tips.net/T000215_Intelligent_Title_Case.html to use an increased set of title words to place in lower case.
In my version way below, I renamed the variable lclist to the descriptive "LowCaseList" and organize it as a concatenation for readability and organization. I sort each functionally related and word-length group for my own logical organization. The order does not influence macro functionality.

' List of lowercase words, surrounded by spaces (concatenated and continued)
LowCaseList = " a an the and but or nor so yet as " & _
"at by in of on to up for off out per pro qua via " & _
"amid atop down from into like near next onto " & _
"over past plus sans save than till upon with " & _
"da de la le van von dans "

First, I have the articles (a an the) along with the common conjunctions.
Then 2-letter and 3-letter prepositions, including Latin origin words.
Then two lines of 4-letter prepositions, including "sans" (adopted into English).
Finally, purely foreign (mostly French) bits, such as those found in the title of the iconic 1902 short film, "Le Voyage dans la Lune" (A Trip to the Moon) by pioneering French filmmaker, Georges Méliès.

Here is my adaptation of Allen's fine macro. All lines are 80 characters or fewer.
-----------------------------------------------------------
Sub TitleCase()
' Set the selection in headline title case.

' Adapted 2011/5/24 by Steve Wells from WordTips by Sharon Parq Associates, and
' amended 2014/7/25 and 2015/5/20.
' Set a selection in title case according to the Microsoft Manual of Style
' heading title rules. (The Chicago Manual of Style differs, recommending
' all prepositions be lowercase, regardless of length.)
' Articles, conjunctions, prepositions (four characters or fewer), and some
' foreign words usually take lowercase, except as the first or last words of
' a title. (The WordTips version did not always capitalize the final word.)

' The result may fail any of the many exceptions from special contexts; such as
' short prepositions in verb phrases, hyphenated forms, and special terms,
' among others that are all beyond the scope of this simple tool.

' When the selection includes an ending paragraph mark, punctuation, or spaces,
' the last word could be problematic. A test shrinks the selection to remove
' such a paragraph mark and/or punctuation if present. Adjustment for titles
' with intra-selection line breaks is beyond the scope of this tool.

Dim LowCaseList, Strng As String
Dim Wrd As Integer

' List of lowercase words, surrounded by spaces (concatenated and continued)
LowCaseList = " a an the and but or nor so yet as " & _
"at by in of on to up for off out per pro qua via " & _
"amid atop down from into like near next onto " & _
"over past plus sans save than till upon with " & _
"da de la le van von dans "

' Exclude a final paragraph mark from the selection.
If Right(Selection.Text, 1) = vbCr Then _
Selection.MoveEnd Unit:=wdCharacter, Count:=-1

' Exclude final punctuation from the selection.
While InStr(".?!:,-–— ", Right(Selection.Text, 1))
Selection.MoveEnd Unit:=wdCharacter, Count:=-1
Wend

' Convert to standard Word title case. Fully uppercase words don't always
' convert properly, so the selection is first converted to lowercase.
Selection.Range.Case = wdLowerCase
Selection.Range.Case = wdTitleWord

' Change words between the first and last ones to lowercase if in the list.
For Wrd = 2 To Selection.Range.Words.Count - 1
Strng = Trim(Selection.Range.Words(Wrd))
Strng = " " & LCase(Strng) & " "
If InStr(LowCaseList, Strng) Then
Selection.Range.Words(Wrd).Case = wdLowerCase
End If
Next Wrd
End Sub