X-ing Out Text

Cindy asked if there is a way to "type over" words with a different character. In particular, she wanted to "x" out some characters. She doesn't want to do a strikethrough, but actually use the "x" character to type over characters already in the document.

The best way to do this in Word is to use EQ field with the \o (overtype) switch. Follow these steps:

1. Position the insertion pointer where you want the x-ed out text to appear.
2. Press Ctrl+F9. Word inserts a set of field braces, with the insertion point in the middle of them.
3. Type the following within the field braces:

     eq \o(my text,xxxxxxx)

1. Replace "my text" with the text you want x-ed out, and make sure there are enough x characters to cover that text.
2. Press Shift+F9 to collapse the field and display the result.

This field approach works great for short text selections, and you could always convert it into a macro if you have lots of text you want to affect in this manner. The following macro carries this concept even further—it displays the overtype x characters in red, and it doesn't overtype spaces:

Sub OverstrikeWithX2()
    Dim i As Integer
    MyString = Selection.Text

    ' Insertion point only/single character/multiple character range handler
    If Selection.Characters.Count = 1 Then
        Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdExtend
        If Selection.Characters.Count = 2 Then
            Selection.MoveLeft Unit:=wdCharacter, Count:=2, Extend:=wdExtend
        Else
            Selection.MoveLeft Unit:=wdCharacter, Count:=1
        End If
    Else
        Selection.MoveLeft Unit:=wdCharacter, Count:=1
    End If
    ' end range handler

    For i = 1 To Len(MyString)
        Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdExtend
        ' paragraph marker and space handler
        If Selection.Text = Chr(13) Or Selection.Text = " " Then
            While Selection.Text = Chr(13) Or Selection.Text = " "
                If i = Len(MyString) Then
                    Selection.MoveRight Unit:=wdCharacter, Count:=1
                    Exit Sub
                Else
                    i = i + 1
                    Selection.MoveRight Unit:=wdCharacter, Count:=1
                    Selection.MoveRight Unit:=wdCharacter, Count:=1, _
                      Extend:=wdExtend
                End If
            Wend
        End If
        ' end paragraph marker & space handler

        With Selection
            .Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, _
              PreserveFormatting:=False
            .TypeText Text:="eq \o("
            .MoveRight Unit:=wdCharacter, Count:=1
            .TypeText Text:=",x)"
            .Delete Unit:=wdCharacter, Count:=1

            ' The next three lines turns the overstike "x" red
            .MoveLeft Unit:=wdCharacter, Count:=1
            .MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdExtend
            .Font.Color = wdColorRed
            .Fields.ToggleShowCodes
            .MoveRight Unit:=wdCharacter, Count:=1
        End With
    Next i
End Sub

The macro adds a single field for each character being overtyped, and is therefore appropriate for text of almost any length.

There is also an entirely different approach you may want to try, this time using text boxes. Create a text box using the Drawing toolbar. Inside of the text box, type as many x characters as desired in the font and size desired. Make sure the text box is formatted so it has no fill (which makes it transparent), has no surrounding line, and floats over text with no text wrapping. Drag the text box over the text to be x-ed out, and size as necessary.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (3921) applies to Microsoft Word 97, 2000, 2002, and 2003.