Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Running Macros Based on Keywords.

Running Macros Based on Keywords

by Allen Wyatt
(last updated August 17, 2017)

Eyal wonders if there is any way to run a macro automatically if a user types in a particular word or phrase.

Unfortunately, there are no Word VBA event procedures that will detect when text is typed into a document. However, Word internally detects when a complete word is entered so that it can carry out such things as spell checking, AutoCorrect, and updating the word count. You cannot tap into this internal detection method, however.

Probably the best approach is to use VBA's timer capability to check whether a word has been entered. (Remember—Word internally updates the word count every time a word is completed, so your timer code can monitor the word count to see if it has changed.) The OnTime method has a minimum setting of one second, which means that your timer-based code can only run once per second. It is possible for a fast typist to type more than one word per second, so your code needs to actually check the last few words entered.

Here is the code you can use:

Dim wCount As Long
Dim aRange As Range
Dim tWords
Dim inactiveSW As Boolean

Sub InitializeTimer()
    tWords = Array("APPLE", "ORANGE", "PEAR")
    wCount = ActiveDocument.Words.Count
    Set aRange = Selection.Range
    aRange.Start = ActiveDocument.Range.Start
    inactiveSW = False
    StartTimer
End Sub
Public Sub StartTimer()
    Application.OnTime When:=Now + TimeValue("00:00:01"), _
    Name:="TestWords"
End Sub
Public Sub TestWords()
    Dim testWord As String
    Dim i As Long
    Dim k As Long
    Dim kw As Long
    Dim xc As Long

    If inactiveSW Then Exit Sub
    With ActiveDocument
        xc = .Range.Words.Count - wCount
        If xc > 0 And xc < 5 Then
            aRange.End = Selection.End
            kw = aRange.Words.Count - 1
            If kw > 0 Then
                For k = kw - xc + 1 To kw
                    testWord = UCase(Trim(aRange.Words(k).Text))
                    For i = 0 To UBound(tWords)
                        If testWord = tWords(i) Then
                            mysub (testWord)
                            Exit For
                        End If
                    Next i
                Next k
            End If
        End If
        wCount = .Range.Words.Count
    End With
    StartTimer
End Sub
Public Sub KillOnTime()
  'cannot stop the timer so set inactive switch
  inactiveSW = True
End Sub
Sub mysub(s As String)
  ' this subroutine is executed when a special word is entered
  MsgBox s
End Sub

The first routine you need to run is the InitializeTimer macro. It sets up the variables that are necessary before actually starting the OnTime method. It then calls the StartTimer macro which actually sets the timer that runs the TestWords macro.

TestWords checks to see if the word count has increased and, if it has, it checks the last five words entered to see if they match any of your trigger words. (The trigger words are set in the tWords array, in the InitializeTimer macro. They should be entered in the array all in uppercase.) If a trigger word is detected, then your code (mysub) is executed, and the trigger word is passed to your code.

It should be noted that it may be possible for the word count to jump by more than five, particularly if text is pasted into the document. If you want the code to check all words that may be pasted into the document, then you'll need to change the checking code line, which is this:

        If xc > 0 And xc < 5 Then

All you need to do is change it to this:

        If xc > 0 Then

If you want to stop the word checking, run the KillOnTime macro, which sets a flag that stops the words from being checked. To later restart checking, just run InitializeTimer again.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (12374) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Running Macros Based on Keywords.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Finding an Unknown Character

Sometimes the characters that appear in a document can be hard to figure out, especially if the document came from someone ...

Discover More

Playing with a Full Deck

Ever need to populate some cells in your worksheet with a range of data, but in random order? Here's a handy macro to get the ...

Discover More

Blocking the First Sentence from File Info

When you save a file, the information from the start of the file is saved in the properties for the document, and can be seen ...

Discover More

Do More in Less Time! Are you ready to harness the full power of Word 2013 to create professional documents? In this comprehensive guide you'll learn the skills and techniques for efficiently building the documents you need for your professional and your personal life. Check out Word 2013 In Depth today!

More WordTips (menu)

Determining an Integer Value

One of the math functions you can use in your macros is the Int function. It provides a way for you to derive an integer ...

Discover More

Converting Text to Uppercase in a Macro

Macros are often used to process documents. If part of the processing involves making text selections uppercase, Word ...

Discover More

Inserting a Paragraph from within a Macro

Macros are often used to process documents, resulting in changes of one manner or another. If you need your macro to add ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 7 - 1?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Word that uses the menu interface (Word 97, Word 2000, Word 2002, or Word 2003)? This site is for you! If you use a later version of Word, visit our WordTips site focusing on the ribbon interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.