Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Reverse Numbered Lists.

Reverse Numbered Lists

by Allen Wyatt
(last updated November 4, 2013)

Word includes a built-in numbered-list feature that you can use to quickly develop your lists. This is great for lists that are in ascending order (1 through 10), but not so great for those you want in descending order (10 through 1).

If you have a need for reverse lists, there is no automatic feature in Word that allows you to create them. One way around this is to simply create your own list numbers and put them in the order desired. The problem with this is that the process is manually intensive. In addition, the regular numbered-list feature of Word can play havoc with your reverse-ordered list if you press Enter at the end of an existing list item.

Another way to handle the situation is to precede each item in your list with a SEQ field to generate the number for the list item. When you are done with the list items, you could then update the fields and sort the paragraphs in descending order. The obvious drawback to this approach is that you need to enter your initial list in reverse order, since the final sort will do the ordering for you. Thus, if you had 10 items, you would enter number 10 first, then number 9, and so on. When you did the sort, the order of the items would be reversed and each item would end up in its final order.

Another drawback to this is that adding items to the list becomes cumbersome, and if you update the fields in your document, the numbers will be thrown off completely. Thus, a more satisfactory approach must be found.

One way is to modify the SEQ field so that it more appropriately shows the intended order of the paragraphs. Using a compound field for the list number can do this, in the following fashion:

{=NP – {SEQ RevList}}

In this instance, the characters NP must be replaced with a number one greater than the number of items in your final list. Thus, if your list consisted of 25 items, then NP would be 26. The SEQ field is used to generate an ascending order of numbers subtracted from NP to give a final reverse-order numbering.

As long as you know the number of paragraphs (items) in your list and you remember to put the field at the beginning of each paragraph, you are in great condition. If you forget either one, your list can be thrown off. To solve this, a macro can come in handy. The following macros (RevList and DoList) will do the trick.

Sub RevList()
    Dim ShowFlag As Boolean
    Dim Numparas As Integer
    Dim Counter As Integer

    Numparas = Selection.Paragraphs.Count
    Selection.MoveLeft Unit:=wdCharacter, Count:=1
    ShowFlag = ActiveWindow.View.ShowFieldCodes
    ActiveWindow.View.ShowFieldCodes = True
    DoList Numparas
    Counter = 1
    While Counter < Numparas
        Selection.Move Unit:=wdParagraph, Count:=1
        DoList Numparas
        Counter = Counter + 1
    Wend
    ActiveWindow.View.ShowFieldCodes = ShowFlag
    ActiveDocument.Select
    ActiveDocument.Fields.Update
End Sub
Private Sub DoList(Cnt As Integer)
    Selection.Extend
    Selection.MoveRight Unit:=wdCharacter, Count:=1
    If InStr(Selection.Text, "SEQ") > 0 Then
        Selection.MoveRight Unit:=wdCharacter, Count:=2
        Selection.Delete Unit:=wdCharacter, Count:=1
    Else
        Selection.Collapse Direction:=wdCollapseStart
    End If
    Selection.Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, _
        PreserveFormatting:=False
    Selection.TypeText Text:="=" & Cnt + 1 & "-"
    Selection.Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, _
        PreserveFormatting:=False
    Selection.TypeText Text:="SEQ RevList"
    With Selection.ParagraphFormat
        .LeftIndent = InchesToPoints(0.5)
        .FirstLineIndent = InchesToPoints(-0.5)
    End With
    Selection.MoveRight Unit:=wdCharacter, Count:=4
    Selection.InsertAfter "." & vbTab
End Sub

To use the macros, simply select the paragraphs to be included in the list, then run RevList, which in turn uses DoList. The proper fields are placed at the beginning of each paragraph (removing any that are there already), and applying a hanging indent to the paragraphs.

If you want to modify the way in which the hanging indent is created, simply change the lines in the DoList macro where the LeftIndent and FirstLineIndent properties are set.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1759) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Reverse Numbered Lists.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Counting Employees in Classes

Excel is very good at counting things, even when those things need to meet specific criteria. This tip shows how you can do a ...

Discover More

Setting Header/Footer Margins

Do you find that there is a lot of extra space around that data on your worksheet when it is printed? Changing the margins in ...

Discover More

Creating a Sort Order

Excel is very flexible in how it can sort your data. You can even create your own custom sort order that is helpful when ...

Discover More

Comprehensive VBA Guide Visual Basic for Applications (VBA) is the language used for writing macros in all Office programs. This complete guide shows both professionals and novices how to master VBA in order to customize the entire Office suite for their needs. Check out Mastering VBA for Office 2010 today!

MORE WORDTIPS (MENU)

Increasing Space between Numbers and Text in a List

You can easily create numbered lists in your document. Most versions of Word even allow you to modify the distance between ...

Discover More

Understanding and Creating Lists

There are two types of common lists you can use in a document: bulleted lists and numbered lists. This tip explains the ...

Discover More

Having Numbered Lists in Subdocuments Restart their Numbering

If you have a bunch of subdocuments, and each of those subdocuments contains numbered lists, you may find that you have ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)

This Site

Got a version of Word that uses the menu interface (Word 97, Word 2000, Word 2002, or Word 2003)? This site is for you! If you use a later version of Word, visit our WordTips site focusing on the ribbon interface.

Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.

Links and Sharing
Share