Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Underlining Quoted Text.

Underlining Quoted Text

by Allen Wyatt
(last updated February 26, 2014)

For some documents, you may have the need to underline information within quotes. For instance, for some legal documents you may need to find all material surrounded by quotes, and then make the information between the quotes underlined. This is different from regular prose writing, where you would use either underlines or quotes, but not both.

If you have a need to search for all quoted text and make it underlined, you can use the following macro. It searches for quote marks and when it finds one, it underlines everything up to the next quote mark. Note that it will not actually underline the quote marks themselves.

Sub UnderlineQuoted()
    Dim bDelQuotes As Boolean
    Dim bMvRt As Boolean
    Selection.HomeKey Unit:=wdStory

    ' controls deletion of quote marks
    bDelQuotes = False
    
    With Selection.Find
        .ClearFormatting
        .Text = Chr(34)
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Execute
    End With

    While Selection.Find.Found
        Selection.MoveRight Unit:=wdCharacter, Count:=1
        ' switch on selection extend mode
        Selection.ExtendMode = True
        bMvRt = True
        ' find second quote of this pair
        Selection.Find.Execute
        If Selection.Find.Found Then
            Selection.MoveLeft Unit:=wdCharacter, Count:=1
            If Len(Selection.Range.Text) > 0 Then
                ' make it underlined
                Selection.Font.Underline = True
                ' delete quote marks, if appropriate
                If bDelQuotes Then
                    Selection.Cut
                    Selection.TypeBackspace
                    Selection.Delete Unit:=wdCharacter, Count:=1
                    Selection.Paste
                    bMvRt = False
                End If
            End If
        End If
        Selection.ExtendMode = False
        If bMvRt Then
            Selection.Collapse Direction:=wdCollapseEnd
            Selection.MoveRight Unit:=wdCharacter, Count:=1
        End If
        Selection.Find.Execute
    Wend
End Sub

Pay attention to the setting of the bDelQuotes variable. If set to False (as it is here), then the quote marks themselves are not deleted by the macro. If you change the value of the variable to True, then the macro gets rid of the quote marks in the document. Note that it only gets rid of the quote marks if it actually underlines text between those quote marks.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1589) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Underlining Quoted Text.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Disappearing Macro Menus

Word is quite versatile in how you can customize it. You can add all sorts of macros to menus, but doing so may cause ...

Discover More

Converting from Works to Word

Got some files in an older version of Works? Here's how to get them into Word.

Discover More

Maintaining Accuracy of Significant Digits

If you work in the sciences or mathematics, you know that significant digits are important. This tip answers questions about ...

Discover More

Learning Made Easy! Quickly teach yourself how to format, publish, and share your content using Word 2013. With Step by Step, you set the pace, building and practicing the skills you need, just when you need them! Check out Microsoft Word 2013 Step by Step today!

More WordTips (menu)

Resetting Default Character Formatting

If you need to remove any explicit character formatting from some text, you'll want to commit the shortcut in this tip to ...

Discover More

Underlining Tabs In Numbered Lists

When Word creates an automatically numbered list, it removes some of your formatting flexibility. One thing you can't seem to ...

Discover More

Replacing Quoted Text with Italics

If you have text surrounded by quotes in a document, you may want to remove the quote marks and make the text that was within ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 2 + 1?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Word that uses the menu interface (Word 97, Word 2000, Word 2002, or Word 2003)? This site is for you! If you use a later version of Word, visit our WordTips site focusing on the ribbon interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.