Printing Comments

If you use comments within your documents, Word allows you to print a comment list to use as a reference. To print a comment list, follow these steps if you are using Word 97 or Word 2000:

1. Select Print from the File menu. Word displays the Print dialog box.
2. Using the Print What drop-down list, select Comments.
3. Click on OK.

Beginning with Word 2002, Microsoft significantly changed the way that Word handles document "markup." This change affected the way in which comments (which are considered part of document markup) are handled. If you are using Word 2002 or Word 2003, you can choose two different ways to print your comments. These options are among those you can choose in the Print What drop-down list:

• Document Showing Markup. This option prints your document with the comments shown in-place, using balloons. This is essentially how you see the comments if you are viewing your document in Print Layout view.
• List of Markup. This option produces a comments list, much like those produced in previous versions of Word.

Understanding that "markup" is a generic term that refers to any changes made in a document (if Track Changes is turned on), printing a List of Markup in Word 2002 and Word 2003 still may not give you what you want, if you want to print only a list of comments. Indeed, the markup list includes all markup, not just comments.

If you want to print just the comments without the other markup, there is no longer a way to do this in Word; that capability ceased with the advent of Word 2002. You can, however, create a macro that will print your comments. The traditional way of printing comments within a macro is to use this single line of code:

ActiveDocument.PrintOut Item:=wdPrintComments

If you use this code in Word 2002 or Word 2003, the result is the same as choosing List of Markup on the Print dialog box. A better approach is to gather all your comments and place them in a new document you can then print.

Sub PrintOnlyComments()
    Dim oThisDoc As Document
    Dim oThatDoc As Document
    Dim c As Comment
    Dim sTemp As String
    Dim iPage As Integer

    Set oThisDoc = ActiveDocument
    Set oThatDoc = Documents.Add

    Application.ScreenUpdating = False
    For Each c In oThisDoc.Comments
        'Find page number of comment
        oThisDoc.Select
        c.Reference.Select
        iPage = Selection.Information(wdActiveEndAdjustedPageNumber)

        'Put info in new document
        oThatDoc.Select
        Selection.EndKey Unit:=wdStory
        sTemp = "Page: " & iPage
        Selection.TypeText Text:=sTemp
        Selection.TypeParagraph
        sTemp = "[" & c.Initial & c.Index & "] " & c.Range
        Selection.TypeText Text:=sTemp
        Selection.TypeParagraph
    Next
    Application.ScreenUpdating = True
End Sub

This macro creates a new document, then steps through each comment in the original document and adds it to the new document. There are three properties that are used in putting the text into the new document: the Initial, Index, and Range properties. The Initial property is the initials of the comment's author, the Index property is the number of the comment within the document, and the Range property is the text of the comment itself.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1046) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Printing Comments.