Loading
Word.Tips.Net WordTips (Menu Interface)

Problems Using Words as Bullets

Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Problems Using Words as Bullets.

Word allows you to customize the bullet and numbering styles defined within the program. For instance, you can pick a different character to use as a bullet, as has been discussed in other issues of WordTips. You can even synthesize a way to use words as "bullets" if you instead define numbered lists (which are closely associated with bulleted lists) that don't use the numbers, but instead have "trailing text" which effectively functions as the "bullet."

The problem with any such approach is that you are still subject to the same problems that plague bulleted and numbered lists in general. (These have been covered in other issues of WordTips.) It is possible to avoid some of the problems by relying on outline numbering instead of bullets or regular numbering, but problems can still easily crop up.

Quite honestly, most Word experts will admit that there are serious problems with Word's automatic numbering and bulleting features. There are many different things that can affect bullet and numbering styles. For instance, if the Automatically Update check box (in the Modify style dialog box) is set for one of your bullet or numbering styles, then it can cause untold problems as users make explicit changes to paragraphs within the document. Similarly, if the numbering or bullet styles are based on other styles, then changes can cascade from one style to another without warning.

To get around potential problems with formatting bulleted or numbered lists, many advocate sidestepping Word's automatic features all together. Instead, you can develop a series of macros that can handle the numbering or application of bullets. For instance, the following macro can be used to explicitly format a paragraph using a word as a bullet:

Public Sub BulletText()
    Dim sBullet As String
    Dim myList As ListTemplate

    sBullet = InputBox("Enter bullet text:", "Bullet Text", "Note:")

    ' Add a new ListTemplate object
    Set myList = ActiveDocument.ListTemplates.Add

    With myList.ListLevels(1)
        .NumberFormat = sBullet
        .TrailingCharacter = wdTrailingTab
        .NumberPosition = InchesToPoints(0.25)
        .Alignment = wdListLevelAlignLeft
        .TextPosition = InchesToPoints(0.75)
        .TabPosition = InchesToPoints(0.75)
        .ResetOnHigher = 0
        .StartAt = 1
        .LinkedStyle = ""
        ' The following sets the font attributes of
        ' the "bullet" text
        With .Font
            .Bold = True
            .Name = "Arial"
            .Size = 10
        End With
    End With
    ' Apply the new ListTemplate to the selected text
    Selection.Range.ListFormat.ApplyListTemplate ListTemplate:=myList
End Sub

This macro prompts you for the text to use as your "bullet" and then formats the selected paragraphs using your specification. Notice that the macro uses objects known as "ListTemplates." These objects are what you see when you glance at the palette of available bullet and numbering options in the tabs of the Bullets and Numbering dialog box. Many of the problems associated with numbering and bullets in Word are related to problems in reliably associating specific ListTemplate objects with specific styles. This macro bypasses those problems by not attempting to do so, but by creating new, custom ListTemplate objects that are applied to individual paragraphs in your document.

The downside of using a macro such as this is that you are relying on explicit formatting rather than on styles. This means that you loose the major benefit of styles, which are consistency and the ability to make universal changes to like-styled paragraphs.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1546) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Problems Using Words as Bullets.

Related Tips:

Comprehensive VBA Guide Visual Basic for Applications (VBA) is the language used for writing macros in all Office programs. This complete guide shows both professionals and novices how to master VBA in order to customize the entire Office suite for their needs. Check out Mastering VBA for Office 2010 today!

 

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 5+3 (To prevent automated submissions and spam.)
 
 
           Commenting Terms

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2016)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2016)

Our Products

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2016 Sharon Parq Associates, Inc.