Loading
Word.Tips.Net WordTips (Menu Interface)

Breaking Lines in E-mail

Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Breaking Lines in E-mail.

Most e-mail client programs—especially those that use plain text instead of HTML—automatically "break" each line of e-mail at 70 or 72 characters. Fortunately, they do not typically break a line in the middle of a word, but do so at the beginning of the word that reaches the 70- or 72-character mark.

Unfortunately, this can have some adverse effects on e-mail you compose in Word. Some of your lines, when viewed by your recipient, can look strange, breaking at less-than-optimal places and generally looking pretty funky. The solution, of course, is for you to break each line when the appropriate place on the line is reached. This way you can control, ahead of time, how your recipient sees your message.

You can do this manually, if desired, by setting your message margins such that there is only 7 or 7.2 inches of space horizontally. You would then use a 12-point monospace font, such as Courier, to type the message. When a word wraps to the next line, simply backspace to the beginning of the word and press the Enter key.

This could get VERY old VERY fast, even if you send only a moderate amount of e-mail. The better solution is to allow Word to do the breaks for you, yet there does not seem to be such a capability in Word. (You can set up your options in Outlook or Outlook Express to automatically break lines for you, but that doesn't give you as fine a control as doing it directly within Word.)

This brings us to macro territory. You can use the following macro to inspect the current document and automatically "chop up" each paragraph so that no line is over 70 characters in length.

Sub ChopItUp()
    Dim DocThis As Document, docThat As Document
    Dim sParRaw As String
    Dim iParCount As Integer, iParOut As Integer
    Dim J As Long, X As Integer
    Dim iLineWidth As Integer
    Dim sLeft As String, sRight As String
    Dim sTemp As String

    iLineWidth = 70

    Set DocThis = ActiveDocument
    Documents.Add
    Set docThat = ActiveDocument
    DocThis.Activate

    iParCount = DocThis.Paragraphs.Count
    iParOut = 0
    For J = 1 To iParCount
        sParRaw = DocThis.Paragraphs(J).Range.Text
        If Right(sParRaw, 1) = Chr(13) Then
            sParRaw = Left(sParRaw, Len(sParRaw) - 1)
        End If

        sRight = sParRaw
        If Len(sRight) > iLineWidth Then
            While Len(sRight) > iLineWidth
                sLeft = Left(sRight, iLineWidth)
                sRight = Mid(sRight, iLineWidth + 1)
                flgDoIt = True
                If Left(sRight, 1) = " " Then
                    sRight = Mid(sRight, 2)
                    flgDoIt = False
                End If
                If Right(sLeft, 1) = " " Then
                    sLeft = Left(sLeft, Len(sLeft) - 1)
                    flgDoIt = False
                End If

                If flgDoIt Then
                    X = InStr(LTrim(sLeft), " ")
                    If X > 0 Then
                        sTemp = ""
                        While Right(sLeft, 1) <> " "
                            sTemp = Right(sLeft, 1) & sTemp
                            sLeft = Left(sLeft, Len(sLeft) - 1)
                            If Len(sLeft) = 0 Then
                                sLeft = sTemp & " "
                                sTemp = ""
                            End If
                        Wend
                        sRight = sTemp & sRight
                    End If
                    sLeft = Trim(sLeft)
                End If

                docThat.Paragraphs.Add
                docThat.Paragraphs(docThat.Paragraphs.Count).Range = sLeft
                sLeft = ""
                sRight = Trim(sRight)
            Wend
        End If
        docThat.Paragraphs.Add
        docThat.Paragraphs(docThat.Paragraphs.Count).Range = sRight
    Next J
End Sub

When you run this macro, it opens a brand new document and copies the information from the old document to it, making sure that each line is no longer than 70 characters. The new document will not contain any formatting. (Since you are putting together plain-text e-mail, this should not be a problem.) If you want a different line width, all you need to do is change the value assigned to iLineWidth in the macro.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1336) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Breaking Lines in E-mail.

Related Tips:

Create Custom Apps with VBA! Discover how to extend the capabilities of Office 2013 (Word, Excel, PowerPoint, Outlook, and Access) with VBA programming, using it for writing macros, automating Office applications, and creating custom applications. Check out Mastering VBA for Office 2013 today!

 

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 5+3 (To prevent automated submissions and spam.)
 
 
           Commenting Terms

Comments for this tip:

Thomas    24 Nov 2015, 07:23
changing 3 lines like shown below, I use this great code to select a text area and get this text formatted to line size 70 in a new window.

' Dim DocThis As Document
    Dim DocThis As Range
    Dim docThat As Document
    Dim sParRaw As String
    Dim iParCount As Integer, iParOut As Integer
    Dim J As Long, X As Integer
    Dim iLineWidth As Integer
    Dim sLeft As String, sRight As String
    Dim sTemp As String

    iLineWidth = 70

' Set DocThis = ActiveDocument
    Set DocThis = Selection.Range
    Documents.Add
    Set docThat = ActiveDocument
' DocThis.Activate
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2016)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2016)

Our Products

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2016 Sharon Parq Associates, Inc.