Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Changing What Is Pasted in a Dialog Box.

Changing What Is Pasted in a Dialog Box

Written by Allen Wyatt (last updated February 26, 2022)
This tip applies to Word 97, 2000, 2002, and 2003


Ihor wants to automate the inserting of a URL hyperlink into a Word document. The URL will be associated with a phrase, such as "click here". He first copies the URL of a specific website to the Clipboard. He then records a macro that opens the Insert Hyperlink dialog box (Ctrl+K) and pastes into the appropriate field the URL from the Clipboard (Ctrl+V) and clicks OK. When he later runs the macro, it gives him the same URL every time he runs it. Ihor wants to paste a different URL into the dialog box every time he runs the macro, but seems to be missing how to do that.

When you record a macro, it is very literal about what it does—it records exactly the steps you take, including how dialog boxes are filled out. The solution isn't to look for ways to paste new information into a dialog box, but to look at how you are creating your hyperlink. Here's what would be recorded if you inserted a hyperlink with the macro recorder running:

Sub Macro1()
'
' Macro1 Macro
'
'
    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= _
        "http://www.tips.net/", SubAddress:="", ScreenTip:="", TextToDisplay:= _
        "click here"
End Sub

What Ihor wants to change is the target for the hyperlink, which is assigned to the Address property; this is what gets "pasted" into the Address field of the dialog box. In order to do this, you could change your macro in a simple manner, such as this:

Sub Macro2()
    Dim sTemp As String
    sTemp = "http://www.tips.net/"

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= sTemp, _
        SubAddress:="", ScreenTip:="", TextToDisplay:= "click here"
End Sub

All that has been done in this example is delete some of the unnecessary comments at the beginning of the macro and create a string variable, sTemp, that now contains the target for the hyperlink. This variable is then assigned to the Address property. In order to change the target, then, one only needs to change the value of the sTemp variable—and there are a number of ways this can be done.

One way is to use an InputBox function to create your own dialog box, in this manner:

Sub Macro3()
    Dim sTemp As String
    Dim sPrompt As String
    Dim sTitle As String

    sPrompt = "Enter the target for the hyperlink"
    sTitle = "Hyperlink Destination"
    sTemp = "http://www.tips.net/"
    sTemp = InputBox(sPrompt, sTitle, sTemp)

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= sTemp, _
        SubAddress:="", ScreenTip:="", TextToDisplay:= "click here"
End Sub

Of course, Ihor mentioned that in his process he actually copies the URL to the Clipboard. If that is the process that he wants to use, it is possible to assign the URL based on whatever is in the Clipboard when the macro is run. Here's how you would do that:

Sub Macro4()
    Dim sTemp As String
    Dim MyData As DataObject
    Set MyData = New DataObject

    MyData.GetFromClipboard
    sTemp = Trim(MyData.GetText(1))

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= sTemp, _
        SubAddress:="", ScreenTip:="", TextToDisplay:= "click here"
End Sub

In order to utilize the Clipboard in this manner, you'll need to set up a reference for the Microsoft Forms in the VBA Editor. (Choose References from the Tools menu in the Editor.)

Note, as well, that all these examples modify what is assigned to the Address property of your new hyperlink. There is a good chance that you'll want to change the macro to modify what is assigned to the TextToDisplay property, as well.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the WordTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (138) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Changing What Is Pasted in a Dialog Box.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Creating Sideheads

A sidehead can be used as a layout element for a document. You can create sideheads in a document by using text boxes, as ...

Discover More

Random Resetting of the Standard Toolbar

Excel allows you to easily customize what appears on its various toolbars. If you make customizations to the Standard ...

Discover More

Single-Character Fractions

Some fractions Word automatically converts to single characters, some it doesn't. Here's why that happens and what you ...

Discover More

Do More in Less Time! Are you ready to harness the full power of Word 2013 to create professional documents? In this comprehensive guide you'll learn the skills and techniques for efficiently building the documents you need for your professional and your personal life. Check out Word 2013 In Depth today!

More WordTips (menu)

Creating a String

Need to use a macro to create a text string? One easy way to do it is to use the String function, described in this tip.

Discover More

Cleaning Up Text in a Macro

Need to remove extraneous characters from a text string? VBA makes it easy through the CleanString method, described in ...

Discover More

Defining a Shortcut for a Macro

You can make running macros very easy if you assign a shortcut key to the macro. This tip demonstrates how easy it is to ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] (all 7 characters, in the sequence shown) in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is five more than 3?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Word that uses the menu interface (Word 97, Word 2000, Word 2002, or Word 2003)? This site is for you! If you use a later version of Word, visit our WordTips site focusing on the ribbon interface.

Videos
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.