Including Headers and Footers when Selecting All

Tim created a simple macro to update all the fields in a template. The macro includes a step that selects the entire document, much like pressing Ctrl+A. This step doesn't select headers and footers, and Tim is afraid that there may be fields to be updated in those locations. He wonders if there is a way to include headers and footers when selecting all, or if there is a different way for his macro to update the fields in the header or footer areas.

The simple answer is that you need to modify your macro code so that it looks in all the different Word areas that there might be fields. The problem with using a "select all" approach is that it only selects text in the main document. Headers, footers, and a host of other elements are maintained in their own separate layers that preclude them from being selected with all the text of the document.

If you simply want to update fields in the main text and in the headers and footers, then you should use a technique such as the following:

Sub MyUpdateFields1()
    ActiveDocument.StoryRanges(wdMainTextStory).Fields.Update
    ActiveDocument.StoryRanges(wdPrimaryFooterStory).Fields.Update
    ActiveDocument.StoryRanges(wdPrimaryHeaderStory).Fields.Update
End Sub

Note that the different layers of a document are referred to as "stories" and maintained within their own collection. While this simple macro very quickly updates the fields in the stories containing the main text, the footers, and the headers, there are other stories (layers) where there could be fields requiring updating. The following macro looks through each story, regardless of its type, and does the requisite updating:

Sub MyUpdateFields2()
    Dim story As Word.Range

    For Each story In ActiveDocument.StoryRanges
        Do
            story.Fields.Update
            ' Check linked stories as linked stories are not independent
            Set story = story.NextStoryRange
        Loop Until (story Is Nothing)
    Next
End Sub

If you really want to be complete, however, there is more than just the different story layers that you need to look through. For instance, it may be that there are some fields contained within text boxes that need updating. A more comprehensive macro is needed to deal with all these other places that fields could be located. In the following example, note the many different elements of the document that can be checked for fields.

Sub MyUpdateFields3()
    Dim doc As Document ' Pointer to Active Document
    Dim wnd As Window ' Pointer to Document's Window
    Dim lngMain As Long ' Main Pane Type Holder
    Dim lngSplit As Long ' Split Type Holder
    Dim lngActPane As Long ' ActivePane Number
    Dim rngStory As Range ' Range Objwct for Looping through Stories
    Dim TOC As TableOfContents ' Table of Contents Object
    Dim TOA As TableOfAuthorities 'Table of Authorities Object
    Dim TOF As TableOfFigures 'Table of Figures Object
    Dim shp As Shape

    ' Set Objects
    Set doc = ActiveDocument
    Set wnd = ActiveDocument.ActiveWindow

    ' get Active Pane Number
    lngActPane = wnd.ActivePane.Index

    ' Hold View Type of Main pane
    lngMain = wnd.Panes(1).View.Type

    ' Hold SplitSpecial
    lngSplit = wnd.View.SplitSpecial

    ' Get Rid of any split
    wnd.View.SplitSpecial = wdPaneNone

    ' Set View to Normal
    wnd.View.Type = wdNormalView

    ' Loop through each story in doc to update
    For Each rngStory In doc.StoryRanges
        If rngStory.StoryType = wdCommentsStory Then
            Application.DisplayAlerts = wdAlertsNone
            ' Update fields
            rngStory.Fields.Update
            Application.DisplayAlerts = wdAlertsAll
        Else
           ' Update fields
           rngStory.Fields.Update
        End If
    Next

    For Each shp In doc.Shapes
        With shp.TextFrame
            If .HasText Then
                shp.TextFrame.TextRange.Fields.Update
            End If
        End With
    Next

    ' Loop through TOC and update
    For Each TOC In doc.TablesOfContents
        TOC.Update
    Next

    ' Loop through TOA and update
    For Each TOA In doc.TablesOfAuthorities
        TOA.Update
    Next

    ' Loop through TOF and update
    For Each TOF In doc.TablesOfFigures
        TOF.Update
    Next

    ' Return Split to original state
    wnd.View.SplitSpecial = lngSplit

    ' Return main pane to original state
    wnd.Panes(1).View.Type = lngMain

    ' Active proper pane
    wnd.Panes(lngActPane).Activate

    ' Close and release all pointers
    Set wnd = Nothing
    Set doc = Nothing
End Sub

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (522) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Including Headers and Footers when Selecting All.