Inserting Multiple Graphics in a Document

Every week John needs to create an invoice and insert several scanned images into a Word document. He wonders if there is a way to put all of the JPG images from a particular folder into the current Word document.

There are a couple of ways you can do this. One way is to simply select all the graphics and insert them in one step:

1. Place the insertion point at the place in the document where you want the graphics inserted.
2. Choose Insert | Picture | From File. Word displays the Insert Picture dialog box.
3. Use the Look In control to locate the folder that contains the images.
4. Press Ctrl+A. Word selects all the files in the folder.
5. Click OK or Insert, depending on your version of Word.

That's it; Word inserts all the graphics in the document. You'll want to be careful doing this, because if there are a lot (more than, say, 100) graphics in the folder or if the graphic files are quite large, you can slow Word to a crawl or hang it completely. If the folder contains more than just graphics or you want only some of the graphic files, you can hold down the Ctrl key as you use the mouse to select graphics in step 4. The point is that whatever files you have selected in step 4, those are the files that Word inserts in your document.

A variation on this approach involves the use of Windows. Follow these general steps:

1. Place the insertion point at the place in the document where you want the graphics inserted.
2. Minimize the Word document.
3. In Windows, display the folder where the images are located.
4. Build a selection set of the images you want inserted in the document.
5. Click on any single image in the selection set and hold down the mouse button.
6. Drag the selection set over the top of the document as it appears in the Taskbar. (Don't release the mouse button quite yet.)
7. Once Windows displays the Word document (which it does after a few seconds), release the mouse button.

At this point, all the images you selected in step 4 are inserted in the Word document, the same as in the earlier method.

If you use either of the foregoing methods, you'll need to resize images and move them around, as necessary, so your document appears the way you desire.

Of course, if you need to insert whole groups of images on a routine basis, then going through these steps can become tiresome after a while. Tedium is often relieved through the use of a macro, and this case is no exception. The following macro can be used to display a dialog box (similar to those used in the earlier methods) where you can select the files you want. When you close the dialog box, any images you selected within the dialog box are inserted in your document, each in its own paragraph.

Sub InsertImages()
    Dim doc As Word.Document
    Dim fd As FileDialog
    Dim vItem As Variant
    Dim mg1 As Range
    Dim mg2 As Range

    Set fd = Application.FileDialog(msoFileDialogFilePicker)
    Set doc = ActiveDocument

    With fd
        .Filters.Add "Images", "*.gif; *.jpg; *.jpeg", 1
        .FilterIndex = 1

        If .Show = -1 Then
            For Each vItem In .SelectedItems
                Set mg2 = ActiveDocument.Range
                mg2.Collapse wdCollapseEnd
                doc.InlineShapes.AddPicture _
                  FileName:=vItem, _
                  LinkToFile:=False, SaveWithDocument:=True, Range:=mg2
                Set mg1 = ActiveDocument.Range
                mg1.Collapse wdCollapseEnd

                mg1.Text = vbCrLF & vbCrLf
            Next vItem
        End If
    End With

    Set fd = Nothing
End Sub

If you don't want to bother with selecting folders or files, you can use an even simpler macro. The following pulls all JPG files from a specified folder and places them in the current document. Each image is in its own paragraph.

Sub GetPictures()
    Dim sPic As String
    Dim sPath As String

    sPath = "c:\myfolder\"
    sPic = Dir(sPath & "*.jpg")

    Do While sPic <> ""
        Selection.InlineShapes.AddPicture _
          FileName:=sPath & sPic, _
          LinkToFile:=False, SaveWithDocument:=True
        sPic = Dir
        Selection.TypeParagraph
        Selection.TypeParagraph
    Loop
End Sub

To use the macro, just make sure you change the value assigned to sPath so that it represents the folder you want.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10726) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Inserting Multiple Graphics in a Document.