Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Removing Pictures from Multiple Files.

Removing Pictures from Multiple Files

Written by Allen Wyatt (last updated June 26, 2018)
This tip applies to Word 97, 2000, 2002, and 2003


Rosario has a huge number of documents (about 44,000 of them), each of which contains a graphic in the header. She is looking for a way to remove all those graphics without the necessity of opening and modifying each document manually.

Fortunately this can be handled by creating a macro. All you need to do is put all the documents in a folder and then use the macro to search through the folder, open each document, remove the graphic, and save each document. This can be done with a macro like the following:

Sub StripGraphics()
    Dim oShape As Shape
    Dim oIShape As InlineShape
    Dim I As Integer
    Dim J As Integer

    With Application.FileSearch
        .LookIn = "C:\MyStuff\"     ' where to search
        .SearchSubFolders = True    ' search the subfolders
        .FileName = "*.doc"         ' file pattern to match

        ' if more than one match, execute the following code
        If .Execute() > 0 Then
            MsgBox "Found " & .FoundFiles.Count & " file(s)."

            ' for each file you find, run this loop
            For I = 1 To .FoundFiles.Count
                ' open the file based on its index position
                Documents.Open FileName:=.FoundFiles(I)

                ' document is now active, check all sections
                For J = 1 To ActiveDocument.Sections.Count
                    With ActiveDocument.Sections(J).Headers(wdHeaderFooterPrimary)
                        ' remove floating graphics from header
                        If .Shapes.Count > 0 Then
                            For Each oShape In .Shapes
                                oShape.Delete
                            Next oShape
                        End If
                        ' remove inline graphics from header
                        If .Range.InlineShapes.Count > 0 Then
                            For Each oIShape In .Range.InlineShapes
                                oIShape.Delete
                            Next oIShape
                        End If
                    End With
                    With ActiveDocument.Sections(J).Headers(wdHeaderFooterFirstPage)
                        ' remove floating graphics from header
                        If .Shapes.Count > 0 Then
                            For Each oShape In .Shapes
                                oShape.Delete
                            Next oShape
                        End If
                        ' remove inline graphics from header
                        If .Range.InlineShapes.Count > 0 Then
                            For Each oIShape In .Range.InlineShapes
                                oIShape.Delete
                            Next oIShape
                        End If
                    End With
                Next J

                ' save and close the current document
                ActiveDocument.Close wdSaveChanges
            Next I
        Else
            MsgBox "No files found."
        End If
    End With
End Sub

This macro makes the assumption that you want to remove all the graphics (both floating and inline) in the header. These are removed, and each file is resaved. The macro doesn't affect any other graphics in the document.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the WordTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (311) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Removing Pictures from Multiple Files.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Copying a Worksheet

Need to make a copy of one of your worksheets? Excel provides a few different ways you can accomplish the task.

Discover More

Creating Add-Ins

Want to create your own add-in? Excel makes it easy to do. Here are all the steps you need.

Discover More

Last Document Saves Not Saved

Click the Save button and you expect your document to be saved, right? What if you later discover it wasn't really saved? ...

Discover More

Do More in Less Time! Are you ready to harness the full power of Word 2013 to create professional documents? In this comprehensive guide you'll learn the skills and techniques for efficiently building the documents you need for your professional and your personal life. Check out Word 2013 In Depth today!

More WordTips (menu)

Duplicating Drawing Objects

Need to duplicate a drawing object? It's easy to do if you use the same editing techniques you are already familiar with.

Discover More

Sending Drawing Objects to the Back or Front

Drawing objects can be placed in a document in such a way that they overlap with each other. If you want to arrange those ...

Discover More

Using Object Anchors

An object anchor is used to signify the point at which an object is inserted into a document. If you want to see these ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] (all 7 characters, in the sequence shown) in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is five more than 3?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Word that uses the menu interface (Word 97, Word 2000, Word 2002, or Word 2003)? This site is for you! If you use a later version of Word, visit our WordTips site focusing on the ribbon interface.

Videos
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.