Loading
Word.Tips.Net WordTips (Menu Interface)

Changing What Is Pasted in a Dialog Box

Please Note: This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Changing What Is Pasted in a Dialog Box.

Ihor wants to automate the inserting of a URL hyperlink into a Word document. The URL will be associated with a phrase, such as "click here". He first copies the URL of a specific website to the Clipboard. He then records a macro that opens the Insert Hyperlink dialog box (Ctrl+K) and pastes into the appropriate field the URL from the Clipboard (Ctrl+V) and clicks OK. When he later runs the macro, it gives him the same URL every time he runs it. Ihor wants to paste a different URL into the dialog box every time he runs the macro, but seems to be missing how to do that.

When you record a macro, it is very literal about what it does—it records exactly the steps you take, including how dialog boxes are filled out. The solution isn't to look for ways to paste new information into a dialog box, but to look at how you are creating your hyperlink. Here's what would be recorded if you inserted a hyperlink with the macro recorder running:

Sub Macro1()
'
' Macro1 Macro
'
'
    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= _
        "http://www.tips.net/", SubAddress:="", ScreenTip:="", TextToDisplay:= _
        "click here"
End Sub

What Ihor wants to change is the target for the hyperlink, which is assigned to the Address property; this is what gets "pasted" into the Address field of the dialog box. In order to do this, you could change your macro in a simple manner, such as this:

Sub Macro2()
    Dim sTemp As String
    sTemp = "http://www.tips.net/"

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= sTemp, _
        SubAddress:="", ScreenTip:="", TextToDisplay:= "click here"
End Sub

All that has been done in this example is delete some of the unnecessary comments at the beginning of the macro and create a string variable, sTemp, that now contains the target for the hyperlink. This variable is then assigned to the Address property. In order to change the target, then, one only needs to change the value of the sTemp variable—and there are a number of ways this can be done.

One way is to use an InputBox function to create your own dialog box, in this manner:

Sub Macro3()
    Dim sTemp As String
    Dim sPrompt As String
    Dim sTitle As String

    sPrompt = "Enter the target for the hyperlink"
    sTitle = "Hyperlink Destination"
    sTemp = "http://www.tips.net/"
    sTemp = InputBox(sPrompt, sTitle, sTemp)

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= sTemp, _
        SubAddress:="", ScreenTip:="", TextToDisplay:= "click here"
End Sub

Of course, Ihor mentioned that in his process he actually copies the URL to the Clipboard. If that is the process that he wants to use, it is possible to assign the URL based on whatever is in the Clipboard when the macro is run. Here's how you would do that:

Sub Macro4()
    Dim sTemp As String
    Dim MyData As DataObject
    Set MyData = New DataObject

    MyData.GetFromClipboard
    sTemp = Trim(MyData.GetText(1))

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= sTemp, _
        SubAddress:="", ScreenTip:="", TextToDisplay:= "click here"
End Sub

In order to utilize the Clipboard in this manner, you'll need to set up a reference for the Microsoft Forms in the VBA Editor. (Choose References from the Tools menu in the Editor.)

Note, as well, that all these examples modify what is assigned to the Address property of your new hyperlink. There is a good chance that you'll want to change the macro to modify what is assigned to the TextToDisplay property, as well.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (138) applies to Microsoft Word 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Word (Word 2007 and later) here: Changing What Is Pasted in a Dialog Box.

Related Tips:

Do More in Less Time! Are you ready to harness the full power of Word 2013 to create professional documents? In this comprehensive guide you'll learn the skills and techniques for efficiently building the documents you need for your professional and your personal life. Check out Word 2013 In Depth today!

 

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 5+3 (To prevent automated submissions and spam.)
 
 
           Commenting Terms

Comments for this tip:

Alex Vera    18 Jun 2015, 07:01
Help me , tell me the secueancias need to copy and paste the hyperlink that is on the clipboard. I sent what I 've done.

In the example of Macro 4 it is what I want but not how to add it to my macro. Thank you.

Sub Macro1()
'
' Macro1 Macro
'
'
    Selection.Find.ClearFormatting
    With Selection.Find
        .Text = "Go to store"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute
    Selection.MoveRight Unit:=wdCharacter, Count:=2
    Selection.EndKey Unit:=wdLine, Extend:=wdExtend
    Selection.MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdExtend
    Selection.Cut
    Selection.TypeBackspace
    Selection.HomeKey Unit:=wdLine, Extend:=wdExtend
    ActiveDocument.DefaultTargetFrame = ""
    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= _
        "http://www.link1.com/1", SubAddress _
        :="", ScreenTip:="", TextToDisplay:="Ir a tienda/Go to store", Target:= _
        "_blank"
End Sub
Scott Morris    08 Sep 2014, 23:19
This is an excellent tip. I have a quick question about it. I want to create a hyperlink from the selected text but the hyperlink will be a calculated string of <URL>+<SelectedText>. How do I identify the selected text as a variable in the macro?

For example, I have a ticket number, 123456, in my document. I want that ticket number to be a link to a ticket system that is a fixed URL ending in the ticket number. http://ticketsystemURL&ticketnumber.
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2016)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2016)

Our Products

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2016 Sharon Parq Associates, Inc.