Capitalizing the First Letter after a Colon

Becca asked if there is a way to create a default setting so that the first letter following a colon will always be a capital letter. Unfortunately there is no built-in way to do this in Word. You can, however, create a macro that can be used to step through your document and make sure that each lowercase letter following a colon (and a space) is converted to uppercase.

Sub CapsAfterColon()
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ": ([a-z])"
        .Replacement.Text = ": \1"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = True
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute

    While Selection.Find.Found
        Selection.Range.Case = wdUpperCase
        Selection.Collapse direction:=wdCollapseEnd
        Selection.Find.Execute
    Wend
End Sub

The macro uses a wildcard search to find instances of a colon followed by a space and a lowercase letter. For each instance found, the text is converted to uppercase. The macro searches for and changes the case of all such instances in the document.