Automatically Formatting Text within Quotes

Subscriber Sandy Weigens asked how to find all text between quotation marks and format it to be bold. The solution needs to be able to handle multiple words between the quote marks--entire phrases that need to be bold. This is an interesting question, and there are several ways that it can be approached.

One approach is to use Word's powerful Find and Replace feature to do just what you need. Follow these steps:

1. Press Ctrl+H or choose Replace from the Edit menu. Word displays the Replace tab of the Find and Replace dialog box. (Click here to see a related figure.)
2. In the Find What box, enter the following:

     ["|"]*["|"]

3. This must be entered just as it is, without spaces. The characters before each bar are regular quote marks. The character after the first vertical bar is an opening smart quote, and the one after the second vertical bar is a closing smart quote. The smart quotes are entered in the dialog box by holding down the Alt key and typing 0147 on the keypad for the first one, and then 0148 for the second one.
4. Move the insertion point to the Replace With box.
5. Click on Format, then Font. Word displays the Replace Font dialog box. (You may need to click on the More button before you can see the Format button.)
6. Click on Bold option in the Font Style list.
7. Click on OK.
8. Make sure the Use Wildcards check box is selected.
9. Click on Replace all.

Notice that when Word is done with this search and replace, it will have bolded not only the text within the quotes, but the quotes themselves. If you want to change the quotes back to normal, you can do another wildcard search, this time looking for simply ["|"|"] (step 2, with the last two quotes being opening and closing smart quotes) and replacing it with Not Bold formatting (step 5).

It is interesting to note that you must search for ["|"]*["|"] and not for "*". The reason for this is quite simple. If you are getting your documents (the ones you are formatting) from someone else, you don't know right off the bat if they used smart quotes, regular quotes, or a combination of both. By using the brackets surrounding the two types of quotes on both sides of a vertical bar, you are telling Word to match with either type of opening or closing quote. When you have Use Wildcards selected, Word discriminates between regular and smart quotes. (It doesn't discriminate if you are using Search and Replace without wildcards turned on.)

If you need to do quite a bit of formatting of information between quotes in this manner, the best bet is to create a macro that you can then add to a menu choice or a toolbar button. Perhaps the easiest way is to simply use the macro recorder to record the above steps. If you prefer, you can utilize the following VBA macro to do the trick:

Sub BoldBetweenQuotes()
' base for a quotes finding macro
    Dim blnSearchAgain As Boolean
    ' move to start of doc
    Selection.HomeKey Unit:=wdStory
     ' start of loop
    Do
        ' set up find of first of quote pair
        With Selection.Find
            .ClearFormatting
            .Text = Chr(34)
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindStop
            .Execute
        End With
        If Selection.Find.Found Then
            Selection.MoveRight Unit:=wdCharacter, Count:=1
            ' switch on selection extend mode
            Selection.Extend
            ' find second quote of this pair
            Selection.Find.Execute
            If Selection.Find.Found Then
                Selection.MoveLeft Unit:=wdCharacter, Count:=1
                ' make it bold
                Selection.Font.Bold = True
                Selection.Collapse Direction:=wdCollapseEnd
                Selection.MoveRight Unit:=wdCharacter, Count:=1
                blnSearchAgain = True
            Else
                blnSearchAgain = False
            End If
        Else
            blnSearchAgain = False
        End If
    Loop While blnSearchAgain
End Sub